build.gradle

   1 buildscript {
   2     repositories {
   3         jcenter()
   4         google()
   5     }
   6     dependencies {
   7         classpath 'com.android.tools.build:gradle:3.6.2'
   8     }
   9 }
  10
  11 apply plugin: 'com.android.application'
  12
  13 repositories {
  14     jcenter()
  15     google()
  16 }
  17 configurations {
  18     smallicu
  19 }
  20 dependencies {
  21     implementation 'com.android.support:appcompat-v7:25.3.1'
  22     implementation 'com.android.support:design:25.3.1'
  23     // Note: you can just replace "smallicu" by implementation
  24     // and remove the "compile files" part if you do not
  25     // care about the size of the apk
  26     smallicu 'com.ibm.icu:icu4j:57.1'
  27     implementation files("$buildDir/icu4j-57.1.small.jar") {
  28         builtBy 'makesmallicu'
  29     }
  30 }
  31
  32 task makesmallicu (type:Exec, dependsOn: configurations.smallicu) {
  33     inputs.file "mksmallicu.sh"
  34     inputs.file "${configurations.smallicu.resolve()[0]}"
  35     outputs.dir "$buildDir"
  36     outputs.file "$buildDir/icu4j-57.1.small.jar"
  37     // necessary due to gradle bug: GRADLE-2638
  38     new File("$buildDir").mkdirs()
  39     commandLine "./mksmallicu.sh", "${configurations.smallicu.resolve()[0]}", "$buildDir/icu4j-57.1.small.jar"
  40 }
  41
  42 def utildir = hasProperty("quickdicUtilDir") ? quickdicUtilDir : "Util"
  43
  44 android {
  45     compileSdkVersion 29
  46     lintOptions {
  47         disable "MissingTranslation"
  48     }
  49     buildTypes {
  50         debug {
  51             applicationIdSuffix ".debug"
  52         }
  53         release {
  54             minifyEnabled true
  55             shrinkResources true
  56         }
  57     }
  58     sourceSets {
  59         main {
  60             manifest.srcFile 'AndroidManifest.xml'
  61             java.srcDirs = ['src', utildir + "/src"]
  62             res.srcDirs = ['res']
  63             assets.srcDirs = ['assets']
  64         }
  65
  66         // Move the build types to build-types/<type>
  67         // For instance, build-types/debug/java, build-types/debug/AndroidManifest.xml, ...
  68         // This moves them out of them default location under src/<type>/... which would
  69         // conflict with src/ being used by the main source set.
  70         // Adding new build types or product flavors should be accompanied
  71         // by a similar customization.
  72         debug.setRoot('build-types/debug')
  73         release.setRoot('build-types/release')
  74     }
  75     defaultConfig {
  76         applicationId 'de.reimardoeffinger.quickdic'
  77         targetSdkVersion 29
  78         resConfigs "de", "es", "eu", "fr", "it", "ja", "pt", "pt-rBR", "ru", "zh-rCN"
  79         minSdkVersion 10
  80     }
  81 }