build.gradle

   1 buildscript {
   2     repositories {
   3         jcenter()
   4         google()
   5     }
   6     dependencies {
   7         classpath 'com.android.tools.build:gradle:3.1.3'
   8     }
   9 }
  10
  11 apply plugin: 'com.android.application'
  12
  13 repositories {
  14     jcenter()
  15     google()
  16 }
  17 configurations {
  18     smallicu
  19 }
  20 dependencies {
  21     implementation 'com.android.support:appcompat-v7:25.3.1'
  22     implementation 'com.android.support:design:25.3.1'
  23     // Note: you can just replace "smallicu" by implementation
  24     // and remove the "compile files" part if you do not
  25     // care about the size of the apk
  26     smallicu 'com.ibm.icu:icu4j:57.1'
  27     implementation files("$buildDir/icu4j-57.1.small.jar") {
  28         builtBy 'makesmallicu'
  29     }
  30 }
  31
  32 task makesmallicu (type:Exec, dependsOn: configurations.smallicu) {
  33     inputs.file "mksmallicu.sh"
  34     inputs.file "${configurations.smallicu.resolve()[0]}"
  35     outputs.dir "$buildDir"
  36     outputs.file "$buildDir/icu4j-57.1.small.jar"
  37     // necessary due to gradle bug: GRADLE-2638
  38     new File("$buildDir").mkdirs()
  39     commandLine "./mksmallicu.sh", "${configurations.smallicu.resolve()[0]}", "$buildDir/icu4j-57.1.small.jar"
  40 }
  41
  42 def utildir = hasProperty("quickdicUtilDir") ? quickdicUtilDir : "Util"
  43
  44 android {
  45     compileSdkVersion 26
  46     buildToolsVersion "27.0.3"
  47     lintOptions {
  48         disable "MissingTranslation"
  49     }
  50     buildTypes {
  51         debug {
  52             applicationIdSuffix ".debug"
  53         }
  54         release {
  55             minifyEnabled true
  56             shrinkResources true
  57         }
  58     }
  59     sourceSets {
  60         main {
  61             manifest.srcFile 'AndroidManifest.xml'
  62             java.srcDirs = ['src', utildir + "/src"]
  63             res.srcDirs = ['res']
  64             assets.srcDirs = ['assets']
  65         }
  66
  67         // Move the build types to build-types/<type>
  68         // For instance, build-types/debug/java, build-types/debug/AndroidManifest.xml, ...
  69         // This moves them out of them default location under src/<type>/... which would
  70         // conflict with src/ being used by the main source set.
  71         // Adding new build types or product flavors should be accompanied
  72         // by a similar customization.
  73         debug.setRoot('build-types/debug')
  74         release.setRoot('build-types/release')
  75     }
  76     defaultConfig {
  77         applicationId 'de.reimardoeffinger.quickdic'
  78         targetSdkVersion 26
  79         resConfigs "de", "es", "fr", "it", "ja", "pt", "pt-rBR", "ru", "zh-rCN"
  80     }
  81 }